bd40601acb
The unstable branch of `yabar` received some minor useful changes: - Fixed missprint (f1b1eff481) - Update information on Debian installation (ce20fe75f7) - Add indicator to show current indicator using `libxkbcommon` (5aa1fb5eb5) The last change requires a `libxkbcommon` as additional build input. Furthermore I thought that it might be better to add the dependencies of unstable (namely `playerctl` and `libxkbcommon`) to the `unstable.nix` to reduce the closure size of the stable build.
52 lines
1.3 KiB
Nix
52 lines
1.3 KiB
Nix
{ stdenv, fetchFromGitHub, cairo, gdk_pixbuf, libconfig, pango, pkgconfig
|
|
, xcbutilwm, alsaLib, wirelesstools, asciidoc, libxslt, makeWrapper, docbook_xsl
|
|
, configFile ? null, lib
|
|
, rev, sha256, version
|
|
}:
|
|
|
|
stdenv.mkDerivation {
|
|
name = "yabar-${version}";
|
|
|
|
src = fetchFromGitHub {
|
|
inherit rev sha256;
|
|
|
|
owner = "geommer";
|
|
repo = "yabar";
|
|
};
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [
|
|
cairo gdk_pixbuf libconfig pango xcbutilwm docbook_xsl
|
|
alsaLib wirelesstools asciidoc libxslt makeWrapper
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteInPlace ./Makefile \
|
|
--replace "\$(shell git describe)" "${version}" \
|
|
--replace "a2x" "${asciidoc}/bin/a2x --no-xmllint"
|
|
'';
|
|
|
|
makeFlags = [ "DESTDIR=$(out)" "PREFIX=/" ];
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/share/yabar/examples
|
|
cp -v examples/*.config $out/share/yabar/examples
|
|
|
|
${lib.optionalString (configFile != null)
|
|
''
|
|
wrapProgram "$out/bin/yabar" \
|
|
--add-flags "-c ${configFile}"
|
|
''
|
|
}
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "A modern and lightweight status bar for X window managers";
|
|
homepage = https://github.com/geommer/yabar;
|
|
license = licenses.mit;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ ma27 ];
|
|
};
|
|
}
|