4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
77 lines
2.1 KiB
Nix
77 lines
2.1 KiB
Nix
{ lib, stdenv, fetchurl, makeWrapper, pkgconfig, nasm, makeDesktopItem
|
|
, alsaLib, flac, gtk2, libvorbis, libvpx, libGLU, libGL
|
|
, SDL2, SDL2_mixer }:
|
|
|
|
let
|
|
version = "20200907";
|
|
rev = "9257";
|
|
revExtra = "93f62bbad";
|
|
|
|
desktopItem = makeDesktopItem {
|
|
name = "eduke32";
|
|
exec = "@out@/bin/${wrapper}";
|
|
comment = "Duke Nukem 3D port";
|
|
desktopName = "Enhanced Duke Nukem 3D";
|
|
genericName = "Duke Nukem 3D port";
|
|
categories = "Game;";
|
|
};
|
|
|
|
wrapper = "eduke32-wrapper";
|
|
|
|
in stdenv.mkDerivation {
|
|
pname = "eduke32";
|
|
inherit version;
|
|
|
|
src = fetchurl {
|
|
url = "http://dukeworld.duke4.net/eduke32/synthesis/latest/eduke32_src_${version}-${rev}-${revExtra}.tar.xz";
|
|
sha256 = "972630059be61ef9564a241b84ef2ee4f69fc85c19ee36ce46052ff2f1ce3bf9";
|
|
};
|
|
|
|
buildInputs = [ alsaLib flac gtk2 libvorbis libvpx libGL libGLU SDL2 SDL2_mixer ];
|
|
|
|
nativeBuildInputs = [ makeWrapper pkgconfig ]
|
|
++ stdenv.lib.optional (stdenv.hostPlatform.system == "i686-linux") nasm;
|
|
|
|
postPatch = ''
|
|
substituteInPlace source/build/src/glbuild.cpp \
|
|
--replace libGLU.so ${libGLU}/lib/libGLU.so
|
|
|
|
for f in glad.c glad_wgl.c ; do
|
|
substituteInPlace source/glad/src/$f \
|
|
--replace libGL.so ${libGL}/lib/libGL.so
|
|
done
|
|
'';
|
|
|
|
NIX_CFLAGS_COMPILE = "-I${SDL2.dev}/include/SDL2 -I${SDL2_mixer}/include/SDL2";
|
|
|
|
makeFlags = [
|
|
"SDLCONFIG=${SDL2}/bin/sdl2-config"
|
|
];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
install -Dm755 -t $out/bin eduke32 mapster32
|
|
|
|
makeWrapper $out/bin/eduke32 $out/bin/${wrapper} \
|
|
--set-default EDUKE32_DATA_DIR /var/lib/games/eduke32 \
|
|
--add-flags '-g "$EDUKE32_DATA_DIR/DUKE3D.GRP"'
|
|
|
|
cp -rv ${desktopItem}/share $out
|
|
substituteInPlace $out/share/applications/eduke32.desktop \
|
|
--subst-var out
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Enhanched port of Duke Nukem 3D for various platforms";
|
|
homepage = "http://eduke32.com";
|
|
license = licenses.gpl2Plus;
|
|
maintainers = with maintainers; [ sander ];
|
|
# Darwin is untested (supported by upstream)
|
|
platforms = platforms.all;
|
|
};
|
|
}
|