From fcfdd268ca3e73022b8b5a8bf3504552b18e19bf Mon Sep 17 00:00:00 2001
From: Delan Azabani <delan@azabani.com>
Date: Thu, 29 Dec 2022 22:07:55 +0800
Subject: [PATCH] osu-lazer-bin: init at 2022.1228.0

---
 pkgs/games/osu-lazer-bin/default.nix | 35 ++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix      |  2 ++
 2 files changed, 37 insertions(+)
 create mode 100644 pkgs/games/osu-lazer-bin/default.nix

diff --git a/pkgs/games/osu-lazer-bin/default.nix b/pkgs/games/osu-lazer-bin/default.nix
new file mode 100644
index 000000000000..6ab5c4470106
--- /dev/null
+++ b/pkgs/games/osu-lazer-bin/default.nix
@@ -0,0 +1,35 @@
+{ appimageTools, lib, fetchurl }:
+
+appimageTools.wrapType2 rec {
+  pname = "osu-lazer-bin";
+  version = "2022.1228.0";
+
+  src = fetchurl {
+    url = "https://github.com/ppy/osu/releases/download/${version}/osu.AppImage";
+    sha256 = "sha256-KDJ6HrnGyM6Brtf66C0r+hbSt/stppe+srChtNSoQ9g=";
+  };
+
+  extraPkgs = pkgs: with pkgs; [ icu ];
+
+  extraInstallCommands =
+    let contents = appimageTools.extract { inherit pname version src; };
+    in ''
+      mv -v $out/bin/${pname}-${version} $out/bin/osu\!
+      install -m 444 -D ${contents}/osu\!.desktop -t $out/share/applications
+      for i in 16 32 48 64 96 128 256 512 1024; do
+        install -D ${contents}/osu\!.png $out/share/icons/hicolor/''${i}x$i/apps/osu\!.png
+      done
+    '';
+
+  meta = with lib; {
+    description = "Rhythm is just a *click* away (AppImage version for score submission and multiplayer)";
+    homepage = "https://osu.ppy.sh";
+    license = with licenses; [
+      mit
+      cc-by-nc-40
+      unfreeRedistributable # osu-framework contains libbass.so in repository
+    ];
+    maintainers = [ maintainers.delan ];
+    platforms = [ "x86_64-linux" ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index f19bc2784f39..0d31ad4d49a6 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -34144,6 +34144,8 @@ with pkgs;
 
   osu-lazer = callPackage ../games/osu-lazer { };
 
+  osu-lazer-bin = callPackage ../games/osu-lazer-bin { };
+
   pro-office-calculator = libsForQt5.callPackage ../games/pro-office-calculator { };
 
   qgo = libsForQt5.callPackage ../games/qgo { };