vieb: init at 3.1.0

pkgs/applications/networking/browsers/vieb/default.nix

@@ -0,0 +1,58 @@
+{ mkYarnPackage, fetchFromGitHub, electron, makeWrapper, makeDesktopItem, lib }:
+
+mkYarnPackage rec {
+  pname = "vieb";
+  version = "3.1.0";
+
+  src = fetchFromGitHub {
+    owner = "jelmerro";
+    repo = pname;
+    rev = version;
+    sha256 = "10l36q75nmqv0azxhmwms6hjicbgyvpk8k6ljrh9d7zxryd3xwz0";
+  };
+
+  packageJSON = ./package.json;
+  yarnLock = ./yarn.lock;
+  yarnNix = ./yarn.nix;
+  yarnFlags = [ "--production" "--offline" ];
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  desktopItem = makeDesktopItem {
+    name = "vieb";
+    exec = "vieb %U";
+    icon = "vieb";
+    desktopName = "Web Browser";
+    genericName = "Web Browser";
+    categories = "Network;WebBrowser;";
+    mimeType = lib.concatStringsSep ";" [
+      "text/html"
+      "application/xhtml+xml"
+      "x-scheme-handler/http"
+      "x-scheme-handler/https"
+    ];
+  };
+
+  postInstall = ''
+    install -Dm0644 {${desktopItem},$out}/share/applications/vieb.desktop
+
+    pushd $out/libexec/vieb/node_modules/vieb/app/img/icons
+    for file in *.png; do
+      install -Dm0644 $file $out/share/icons/hicolor/''${file//.png}/apps/vieb.png
+    done
+    popd
+
+    makeWrapper ${electron}/bin/electron $out/bin/vieb \
+      --add-flags $out/libexec/vieb/node_modules/vieb/app
+  '';
+
+  distPhase = ":"; # disable useless $out/tarballs directory
+
+  meta = with lib; {
+    homepage = "https://vieb.dev/";
+    description = "Vim Inspired Electron Browser";
+    maintainers = with maintainers; [ gebner ];
+    platforms = platforms.unix;
+    license = licenses.gpl3;
+  };
+}

pkgs/applications/networking/browsers/vieb/package.json

@@ -0,0 +1,45 @@
+{
+  "name": "vieb",
+  "productName": "Vieb",
+  "version": "3.1.0",
+  "description": "Vim Inspired Electron Browser",
+  "main": "app/index.js",
+  "babel": {
+    "plugins": [
+      "@babel/plugin-proposal-optional-chaining"
+    ]
+  },
+  "scripts": {
+    "test": "jest -u && eslint .",
+    "start": "electron app",
+    "build": "node build.js",
+    "buildall": "node build.js --linux --win --mac",
+    "buildlinux": "node build.js --linux",
+    "buildwin": "node build.js --win",
+    "buildmac": "node build.js --mac"
+  },
+  "repository": "https://github.com/Jelmerro/Vieb",
+  "homepage": "https://vieb.dev",
+  "keywords": [
+    "Electron",
+    "Browser",
+    "Internet"
+  ],
+  "author": "Jelmer van Arnhem",
+  "email": "Jelmerro@users.noreply.github.com",
+  "license": "GPL-3.0+",
+  "devDependencies": {
+    "@babel/plugin-proposal-optional-chaining": "^7.12.7",
+    "archiver": "^5.0.2",
+    "electron": "^11.0.3",
+    "electron-builder": "^22.9.1",
+    "eslint": "^7.15.0",
+    "jest": "^26.6.3"
+  },
+  "dependencies": {
+    "@cliqz/adblocker-electron": "^1.18.8",
+    "darkreader": "^4.9.26",
+    "is-svg": "^4.2.1",
+    "rimraf": "^3.0.2"
+  }
+}

pkgs/top-level/all-packages.nix

@@ -23265,6 +23265,10 @@ in
 
   owamp = callPackage ../applications/networking/owamp { };
 
+  vieb = callPackage ../applications/networking/browsers/vieb {
+    electron = electron_11;
+  };
+
   vivaldi = callPackage ../applications/networking/browsers/vivaldi {};
 
   vivaldi-ffmpeg-codecs = callPackage ../applications/networking/browsers/vivaldi/ffmpeg-codecs.nix {};