BoomMicrophone/nixpkgs-suyu
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity

Merge pull request #280309 from hmenke/mpip

Browse source 
pfft: init at 1.0.8-alpha; pnfft: init at 1.0.7-alpha
This commit is contained in:
markuskowa 2024-01-18 13:19:21 +01:00 committed by GitHub
commit f6e0a8891c
No known key found for this signature in database
GPG key ID: B5690EEEBB952194
2 changed files with 105 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

52
pkgs/by-name/pf/pfft/package.nix Normal file
View file

@ -0,0 +1,52 @@
{ autoreconfHook
, fetchFromGitHub
, fftwMpi
, lib
, llvmPackages
, mpi
, precision ? "double"
, stdenv
}:
assert lib.elem precision [ "single" "double" "long-double" ];
let
fftw' = fftwMpi.override { inherit precision; };
in
stdenv.mkDerivation (finalAttrs: {
pname = "pfft-${precision}";
version = "1.0.8-alpha";
src = fetchFromGitHub {
owner = "mpip";
repo = "pfft";
rev = "v${finalAttrs.version}";
hash = "sha256-T5nPlkPKjYYRCuT1tSzXNJTPs/o6zwJMv9lPCWOwabw=";
};
outputs = [ "out" "dev" ];
nativeBuildInputs = [ autoreconfHook ];
preConfigure = ''
export FCFLAGS="-I${lib.getDev fftw'}/include"
'';
configureFlags = [
"--enable-portable-binary"
] ++ lib.optional (precision != "double") "--enable-${precision}";
buildInputs = lib.optional stdenv.cc.isClang llvmPackages.openmp;
propagatedBuildInputs = [ fftw' mpi ];
doCheck = true;
meta = {
description = "Parallel fast Fourier transforms";
homepage = "https://www-user.tu-chemnitz.de/~potts/workgroup/pippig/software.php.en#pfft";
license = lib.licenses.gpl3Plus;
maintainers = with lib.maintainers; [ hmenke ];
platforms = lib.platforms.linux;
};
})

53
pkgs/by-name/pn/pnfft/package.nix Normal file
View file

@ -0,0 +1,53 @@
{ autoreconfHook
, fetchurl
, fftwMpi
, gsl
, lib
, llvmPackages
, pfft
, precision ? "double"
, stdenv
}:
assert lib.elem precision [ "single" "double" "long-double" ];
let
fftw' = fftwMpi.override { inherit precision; };
pfft' = pfft.override { inherit precision; };
in
stdenv.mkDerivation (finalAttrs: {
pname = "pnfft-${precision}";
version = "1.0.7-alpha";
src = fetchurl {
url = "https://www-user.tu-chemnitz.de/~potts/workgroup/pippig/software/pnfft-${finalAttrs.version}.tar.gz";
hash = "sha256-/aVY/1fuMRl1Q2O7bmc5M4aA0taGD+fcQgCdhVYr1no=";
};
outputs = [ "out" "dev" ];
nativeBuildInputs = [ autoreconfHook ];
preConfigure = ''
export FCFLAGS="-I${lib.getDev fftw'}/include -I${lib.getDev pfft'}/include"
'';
configureFlags = [
"--enable-threads"
"--enable-portable-binary"
] ++ lib.optional (precision != "double") "--enable-${precision}";
buildInputs = [ gsl ] ++ lib.optional stdenv.cc.isClang llvmPackages.openmp;
propagatedBuildInputs = [ pfft' ];
doCheck = true;
meta = {
description = "Parallel nonequispaced fast Fourier transforms";
homepage = "https://www-user.tu-chemnitz.de/~potts/workgroup/pippig/software.php.en#pnfft";
license = lib.licenses.gpl3Plus;
maintainers = with lib.maintainers; [ hmenke ];
platforms = lib.platforms.linux;
};
})