Merge pull request #255084 from aviallon/feature/init-dns-lexicon

python310Packages.dns-lexicon: init at 3.14.1 and add aviallon to maintainers

maintainers/maintainer-list.nix

@@ -1768,6 +1768,15 @@
     githubId = 1222;
     name = "Aaron VonderHaar";
   };
+  aviallon = {
+    email = "antoine-nixos@lesviallon.fr";
+    github = "aviallon";
+    githubId = 7479436;
+    name = "Antoine Viallon";
+    keys = [{
+      fingerprint = "4AC4 A28D 7208 FC6F 2B51  5EA9 D126 B13A B555 E16F";
+    }];
+  };
   avitex = {
     email = "theavitex@gmail.com";
     github = "avitex";

pkgs/development/python-modules/dns-lexicon/default.nix

@@ -0,0 +1,84 @@
+{ buildPythonPackage
+, fetchFromGitHub
+, poetry-core
+, beautifulsoup4
+, cryptography
+, importlib-metadata
+, pyyaml
+, requests
+, tldextract
+, pytestCheckHook
+, pytest-vcr
+# Optional depedencies
+, boto3
+, localzone
+, softlayer
+, zeep
+, dnspython
+, oci
+, lib
+}:
+
+buildPythonPackage rec {
+  pname = "dns_lexicon";
+  version = "3.14.1";
+  format = "pyproject";
+
+  src = fetchFromGitHub {
+    owner = "Analogj";
+    repo = "lexicon";
+    rev = "v${version}";
+    hash = "sha256-flK2G9mdUWMUACQPo6TqYZ388EacIqkq//tCzUS+Eo8=";
+  };
+
+  nativeBuildInputs = [ poetry-core ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    pytest-vcr
+  ] ++ passthru.optional-dependencies.full;
+
+  propagatedBuildInputs = [
+    beautifulsoup4
+    cryptography
+    importlib-metadata
+    pyyaml
+    requests
+    tldextract
+  ];
+
+  passthru.optional-dependencies = {
+    route53 = [ boto3 ];
+    localzone = [ localzone ];
+    softlayer = [ softlayer ];
+    ddns = [ dnspython ];
+    duckdns = [ dnspython ];
+    oci = [ oci ];
+    full = [ boto3 localzone softlayer zeep dnspython oci ];
+  };
+
+  pytestFlagsArray = [
+    "tests/"
+  ];
+
+  disabledTestPaths = [
+    # Needs network access
+    "tests/providers/test_auto.py"
+
+    # Needs network access (and an API token)
+    "tests/providers/test_namecheap.py"
+  ];
+
+  pythonImportsCheck = [
+    "lexicon"
+  ];
+
+  meta = with lib; {
+    description = "Manipulate DNS records on various DNS providers in a standardized way";
+    homepage = "https://github.com/AnalogJ/lexicon";
+    changelog = "https://github.com/AnalogJ/lexicon/blob/v${version}/CHANGELOG.md";
+    maintainers = with maintainers; [ aviallon ];
+    license = with licenses; [ mit ];
+  };
+
+}

pkgs/top-level/python-packages.nix

@@ -3140,6 +3140,8 @@ self: super: with self; {
 
   dnspython = callPackage ../development/python-modules/dnspython { };
 
+  dns-lexicon = callPackage ../development/python-modules/dns-lexicon { };
+
   doc8 = callPackage ../development/python-modules/doc8 { };
 
   docformatter = callPackage ../development/python-modules/docformatter { };