linuxwave: use zigHook

Also, a cosmetic refactor:

- Reorder parameter listing
- Use rec-less, overlay-style overridable recursive attributes (in effect since
NixOS#119942);
- Remove nested with (according to
https://nix.dev/recipes/best-practices#with-scopes)

pkgs/tools/audio/linuxwave/default.nix

@@ -2,62 +2,36 @@
 , stdenv
 , fetchFromGitHub
 , installShellFiles
-, zig
+, zigHook
 }:
 
-stdenv.mkDerivation rec {
+stdenv.mkDerivation (finalAttrs: {
   pname = "linuxwave";
   version = "0.1.5";
 
   src = fetchFromGitHub {
     owner = "orhun";
     repo = "linuxwave";
-    rev = "v${version}";
-    hash = "sha256-5c8h9bAe3Qv7PJ3PPcwMJYKPlWsmnqshe6vLIgtdDiQ=";
+    rev = "v${finalAttrs.version}";
     fetchSubmodules = true;
+    hash = "sha256-5c8h9bAe3Qv7PJ3PPcwMJYKPlWsmnqshe6vLIgtdDiQ=";
   };
 
   nativeBuildInputs = [
     installShellFiles
-    zig
+    zigHook
   ];
 
-  postConfigure = ''
-    export XDG_CACHE_HOME=$(mktemp -d)
-  '';
-
-  buildPhase = ''
-    runHook preBuild
-
-    zig build -Drelease-safe -Dcpu=baseline
-
-    runHook postBuild
-  '';
-
-  checkPhase = ''
-    runHook preCheck
-
-    zig build test
-
-    runHook postCheck
-  '';
-
-  installPhase = ''
-    runHook preInstall
-
-    zig build -Drelease-safe -Dcpu=baseline --prefix $out install
-
+  postInstall = ''
     installManPage man/linuxwave.1
-
-    runHook postInstall
   '';
 
-  meta = with lib; {
-    description = "Generate music from the entropy of Linux";
+  meta = {
     homepage = "https://github.com/orhun/linuxwave";
-    changelog = "https://github.com/orhun/linuxwave/blob/${src.rev}/CHANGELOG.md";
-    license = licenses.mit;
-    maintainers = with maintainers; [ figsoda ];
-    platforms = platforms.all;
+    description = "Generate music from the entropy of Linux";
+    changelog = "https://github.com/orhun/linuxwave/blob/${finalAttrs.src.rev}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ figsoda ];
+    inherit (zigHook.meta) platforms;
   };
-}
+})