Add package 'morituri', a CD ripper.

pkgs/applications/audio/morituri/default.nix

@@ -0,0 +1,58 @@
+{ stdenv, fetchurl, python, pythonPackages, cdparanoia, cdrdao
+, pygobject, gst_python, gst_plugins_base, gst_plugins_good
+, setuptools, utillinux, makeWrapper }:
+
+stdenv.mkDerivation rec {
+  name = "morituri-${version}";
+  version = "0.2.3";
+
+  src = fetchurl {
+    url = "http://thomas.apestaart.org/download/morituri/${name}.tar.bz2";
+    sha256 = "1b30bs1y8azl04izsrl01gw9ys0lhzkn5afxi4p8qbiri2h4v210";
+  };
+
+  pythonPath = [
+    pygobject gst_python pythonPackages.musicbrainzngs
+    pythonPackages.pycdio pythonPackages.pyxdg setuptools
+  ];
+
+  buildInputs = [
+    python cdparanoia cdrdao utillinux makeWrapper
+    gst_plugins_base gst_plugins_good
+  ] ++ pythonPath;
+
+  patches = [ ./paths.patch ];
+
+  postPatch =  ''
+    substituteInPlace morituri/extern/python-command/scripts/help2man \
+      --replace /usr/bin/python ${python}/bin/python
+
+    substituteInPlace morituri/common/program.py \
+      --replace umount ${utillinux}/bin/umount \
+      --replace \'eject \'${utillinux}/bin/eject
+
+    substituteInPlace morituri/program/cdparanoia.py \
+      --replace '"cdparanoia"' '"${cdparanoia}/bin/cdparanoia"'
+
+    substituteInPlace morituri/program/cdrdao.py \
+      --replace "['cdrdao', ]" "['${cdrdao}/bin/cdrdao', ]" \
+      --replace '"cdrdao"' '"${cdrdao}/bin/cdrdao"'
+  '';
+
+  # This package contains no binaries to patch or strip.
+  dontPatchELF = true;
+  dontStrip = true;
+
+  postInstall = ''
+    wrapProgram "$out/bin/rip" \
+      --prefix PYTHONPATH : "$PYTHONPATH" \
+      --prefix GST_PLUGIN_SYSTEM_PATH : "$GST_PLUGIN_SYSTEM_PATH"
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = http://thomas.apestaart.org/morituri/trac/;
+    description = "A CD ripper aiming for accuracy over speed";
+    maintainers = [ maintainers.rycee ];
+    license = licenses.gpl3Plus;
+  };
+}

pkgs/applications/audio/morituri/paths.patch

@@ -0,0 +1,12 @@
+diff -Nurp morituri-0.2.3-orig/doc/Makefile.in morituri-0.2.3/doc/Makefile.in
+--- morituri-0.2.3-orig/doc/Makefile.in	2014-11-01 00:13:01.231364181 +0100
++++ morituri-0.2.3/doc/Makefile.in	2014-11-01 00:13:56.691812229 +0100
+@@ -486,7 +486,7 @@ morituri.ics: $(top_srcdir)/morituri.doa
+ 	-moap doap -f $(top_srcdir)/morituri.doap ical > morituri.ics
+ 
+ rip.1: $(top_srcdir)/morituri/extern/python-command/scripts/help2man $(top_srcdir)/morituri
+-	PYTHONPATH=$(top_srcdir) $(PYTHON) $(top_srcdir)/morituri/extern/python-command/scripts/help2man morituri.rip.main.Rip rip > rip.1
++	PYTHONPATH=$(top_srcdir):$(PYTHONPATH) $(PYTHON) $(top_srcdir)/morituri/extern/python-command/scripts/help2man morituri.rip.main.Rip rip > rip.1
+ 
+ clean-local:
+ 	@rm -rf reference

pkgs/top-level/all-packages.nix

@@ -1554,6 +1554,8 @@ let
 
   mmv = callPackage ../tools/misc/mmv { };
 
+  morituri = callPackage ../applications/audio/morituri { };
+
   most = callPackage ../tools/misc/most { };
 
   multitail = callPackage ../tools/misc/multitail { };