diff --git a/pkgs/applications/networking/browsers/lagrange/default.nix b/pkgs/applications/networking/browsers/lagrange/default.nix
new file mode 100644
index 000000000000..4ade911e1c7b
--- /dev/null
+++ b/pkgs/applications/networking/browsers/lagrange/default.nix
@@ -0,0 +1,44 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, cmake
+, pkg-config
+, libunistring
+, openssl
+, pcre
+, SDL2
+, AppKit
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lagrange";
+  version = "1.0.3";
+
+  src = fetchFromGitHub {
+    owner = "skyjake";
+    repo = "lagrange";
+    rev = "v${version}";
+    sha256 = "1l9qcymjwg3wzbbi4hcyzfrxyqgz2xdy4ab3lr0zq38v025d794n";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [ cmake pkg-config ];
+
+  buildInputs = [ libunistring openssl pcre SDL2 ]
+    ++ lib.optional stdenv.isDarwin AppKit;
+
+  hardeningDisable = lib.optional (!stdenv.cc.isClang) "format";
+
+  installPhase = if stdenv.isDarwin then ''
+    mkdir -p $out/Applications
+    mv Lagrange.app $out/Applications
+  '' else null;
+
+  meta = with lib; {
+    description = "A Beautiful Gemini Client";
+    homepage = "https://gmi.skyjake.fi/lagrange/";
+    license = licenses.bsd2;
+    maintainers = with maintainers; [ sikmir ];
+    platforms = platforms.unix;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 30787fac2c29..a0fa667ba7c2 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5375,6 +5375,10 @@ in
 
   kristall = libsForQt5.callPackage ../applications/networking/browsers/kristall { };
 
+  lagrange = callPackage ../applications/networking/browsers/lagrange {
+    inherit (darwin.apple_sdk.frameworks) AppKit;
+  };
+
   kzipmix = pkgsi686Linux.callPackage ../tools/compression/kzipmix { };
 
   ma1sd = callPackage ../servers/ma1sd { };