free42: init at 2.5.24a

pkgs/applications/misc/free42/default.nix

@@ -0,0 +1,65 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, pkg-config
+, gtk3
+, alsaLib
+}:
+
+stdenv.mkDerivation rec {
+  pname = "free42";
+  version = "2.5.24a";
+
+  src = fetchFromGitHub {
+    owner = "thomasokken";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "xP0kzpmX6Q5Dg7azvyUZIdoi52AYkUmiCkUA1aVY+nQ=";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ gtk3 alsaLib ];
+
+  postPatch = ''
+    sed -i -e "s|/bin/ls|ls|" gtk/Makefile
+  '';
+
+  dontConfigure = true;
+
+  buildPhase = ''
+    runHook preBuild
+    make -C gtk cleaner
+    make --jobs=$NIX_BUILD_CORES -C gtk
+    make -C gtk clean
+    make --jobs=$NIX_BUILD_CORES -C gtk BCD_MATH=1
+    runHook postBuild
+  '';
+
+  preInstall = ''
+    install --directory $out/bin \
+                        $out/share/doc/${pname} \
+                        $out/share/${pname}/skins \
+                        $out/share/icons/hicolor/48x48/apps \
+                        $out/share/icons/hicolor/128x128/apps
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -m755 gtk/free42dec gtk/free42bin $out/bin
+    install -m644 gtk/README $out/share/doc/${pname}/README-GTK
+    install -m644 README $out/share/doc/${pname}/README
+
+    install -m644 gtk/icon-48x48.xpm $out/share/icons/hicolor/48x48/apps
+    install -m644 gtk/icon-128x128.xpm $out/share/icons/hicolor/128x128/apps
+    install -m644 skins/* $out/share/${pname}/skins
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/thomasokken/free42";
+    description = "A software clone of HP-42S Calculator";
+    license = licenses.gpl2Only;
+    maintainers = with maintainers; [ AndersonTorres ];
+    platforms = with platforms; unix;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -4350,6 +4350,8 @@ in
     gtk = gtk3;
   };
 
+  free42 = callPackage ../applications/misc/free42 { };
+
   galen = callPackage ../development/tools/galen {};
 
   gallery-dl = python3Packages.callPackage ../applications/misc/gallery-dl { };