From 64d63907d8083c6e569b12f30a7fa1212ba04bd5 Mon Sep 17 00:00:00 2001
From: lassulus <lassulus@lassul.us>
Date: Wed, 27 Sep 2017 17:44:35 +0200
Subject: [PATCH] electron-cash: init at 2.9.3

---
 .../misc/electron-cash/default.nix            | 66 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 68 insertions(+)
 create mode 100644 pkgs/applications/misc/electron-cash/default.nix

diff --git a/pkgs/applications/misc/electron-cash/default.nix b/pkgs/applications/misc/electron-cash/default.nix
new file mode 100644
index 000000000000..a45ab59ace8e
--- /dev/null
+++ b/pkgs/applications/misc/electron-cash/default.nix
@@ -0,0 +1,66 @@
+{ stdenv, fetchFromGitHub, python2Packages }:
+
+python2Packages.buildPythonApplication rec {
+  version = "2.9.3";
+  name = "electron-cash-${version}";
+
+  src = fetchFromGitHub {
+    owner = "fyookball";
+    repo = "electrum";
+    rev = version;
+    sha256 = "1r39b5ag5fipzgr84pzb53cfm8a4dy53257608754dwr1gfpma3v";
+  };
+
+  propagatedBuildInputs = with python2Packages; [
+    dns
+    ecdsa
+    jsonrpclib
+    pbkdf2
+    pyaes
+    pycrypto
+    pyqt4
+    pysocks
+    qrcode
+    requests
+    tlslite
+
+    # plugins
+    keepkey
+    trezor
+  ];
+
+  preBuild = ''
+    sed -i 's,usr_share = .*,usr_share = "'$out'/share",g' setup.py
+    pyrcc4 icons.qrc -o gui/qt/icons_rc.py
+    # Recording the creation timestamps introduces indeterminism to the build
+    sed -i '/Created: .*/d' gui/qt/icons_rc.py
+  '';
+
+  postInstall = ''
+    # Despite setting usr_share above, these files are installed under
+    # $out/nix ...
+    mv $out/lib/python2.7/site-packages/nix/store"/"*/share $out
+    rm -rf $out/lib/python2.7/site-packages/nix
+
+    substituteInPlace $out/share/applications/electron.desktop \
+      --replace "Exec=electrum %u" "Exec=$out/bin/electrum %u"
+  '';
+
+  doInstallCheck = true;
+  installCheckPhase = ''
+    $out/bin/electrum help >/dev/null
+  '';
+
+  meta = with stdenv.lib; {
+    description = "A lightweight Bitcoin wallet";
+    longDescription = ''
+      An easy-to-use Bitcoin client featuring wallets generated from
+      mnemonic seeds (in addition to other, more advanced, wallet options)
+      and the ability to perform transactions without downloading a copy
+      of the blockchain.
+    '';
+    homepage = https://www.electroncash.org/;
+    maintainers = with maintainers; [ lassulus ];
+    license = licenses.mit;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 72ddcb185e02..48be843c86b4 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -14050,6 +14050,8 @@ with pkgs;
 
   ekho = callPackage ../applications/audio/ekho { };
 
+  electron-cash = callPackage ../applications/misc/electron-cash { };
+
   electrum = callPackage ../applications/misc/electrum { };
 
   electrum-dash = callPackage ../applications/misc/electrum-dash { };