From 34692813e8145074722a284aa13b6c3ed4892694 Mon Sep 17 00:00:00 2001
From: OPNA2608 <christoph.neidahl@gmail.com>
Date: Thu, 13 Jul 2023 19:33:29 +0200
Subject: [PATCH] libayatana-common: init at 0.9.8

---
 .../libraries/libayatana-common/default.nix   | 78 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  4 +
 2 files changed, 82 insertions(+)
 create mode 100644 pkgs/development/libraries/libayatana-common/default.nix

diff --git a/pkgs/development/libraries/libayatana-common/default.nix b/pkgs/development/libraries/libayatana-common/default.nix
new file mode 100644
index 000000000000..aa818a04abea
--- /dev/null
+++ b/pkgs/development/libraries/libayatana-common/default.nix
@@ -0,0 +1,78 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, gitUpdater
+, testers
+, cmake
+, cmake-extras
+, glib
+, gobject-introspection
+, gtest
+, intltool
+, pkg-config
+, systemd
+, vala
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "libayatana-common";
+  version = "0.9.8";
+
+  src = fetchFromGitHub {
+    owner = "AyatanaIndicators";
+    repo = "libayatana-common";
+    rev = finalAttrs.version;
+    hash = "sha256-5cHFjBQ3NgNaoprPrFytnrwBRL7gDG7QZLWomgGBJMg=";
+  };
+
+  postPatch = ''
+    # Queries via pkg_get_variable, can't override prefix
+    substituteInPlace data/CMakeLists.txt \
+      --replace 'DESTINATION "''${SYSTEMD_USER_UNIT_DIR}"' 'DESTINATION "${placeholder "out"}/lib/systemd/user"'
+  '';
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    cmake
+    gobject-introspection
+    intltool
+    pkg-config
+    vala
+  ];
+
+  buildInputs = [
+    cmake-extras
+    glib
+    systemd
+  ];
+
+  checkInputs = [
+    gtest
+  ];
+
+  cmakeFlags = [
+    "-DENABLE_TESTS=${lib.boolToString finalAttrs.doCheck}"
+    "-DENABLE_LOMIRI_FEATURES=OFF"
+    "-DGSETTINGS_LOCALINSTALL=ON"
+    "-DGSETTINGS_COMPILE=ON"
+  ];
+
+  doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+  passthru = {
+    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+    updateScript = gitUpdater { };
+  };
+
+  meta = with lib; {
+    description = "Common functions for Ayatana System Indicators";
+    homepage = "https://github.com/AyatanaIndicators/libayatana-common";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ OPNA2608 ];
+    platforms = platforms.linux;
+    pkgConfigModules = [
+      "libayatana-common"
+    ];
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index fbbf96a987df..b505d7db148a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -21961,6 +21961,10 @@ with pkgs;
 
   libavif = callPackage ../development/libraries/libavif { };
 
+  libayatana-common = callPackage ../development/libraries/libayatana-common {
+    inherit (lomiri) cmake-extras;
+  };
+
   libb2 = callPackage ../development/libraries/libb2 { };
 
   libbacktrace = callPackage ../development/libraries/libbacktrace { };