From 141acc16dc907ab426d26a93672cd734734d449c Mon Sep 17 00:00:00 2001
From: Bernardo Meurer <bernardo@meurer.org>
Date: Mon, 12 Sep 2022 16:05:29 -0300
Subject: [PATCH] wineasio: init at 1.1.0

---
 .../emulators/wineasio/default.nix            | 53 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 55 insertions(+)
 create mode 100644 pkgs/applications/emulators/wineasio/default.nix

diff --git a/pkgs/applications/emulators/wineasio/default.nix b/pkgs/applications/emulators/wineasio/default.nix
new file mode 100644
index 000000000000..5a47111610d1
--- /dev/null
+++ b/pkgs/applications/emulators/wineasio/default.nix
@@ -0,0 +1,53 @@
+{ multiStdenv
+, lib
+, fetchFromGitHub
+, libjack2
+, pkg-config
+, wineWowPackages
+, pkgsi686Linux
+}:
+
+multiStdenv.mkDerivation rec {
+  pname = "wineasio";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = pname;
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-HEnJj9yfXe+NQuPATMpPvseFs+3TkiMLd1L+fIfQd+o=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [ pkg-config wineWowPackages.stable ];
+
+  buildInputs = [ pkgsi686Linux.libjack2 libjack2 ];
+
+  dontConfigure = true;
+
+  makeFlags = [ "PREFIX=${wineWowPackages.stable}" ];
+
+  buildPhase = ''
+    runHook preBuild
+    make "''${makeFlags[@]}" 32
+    make "''${makeFlags[@]}" 64
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -D build32/wineasio.dll $out/lib/wine/i386-windows/wineasio.dll
+    install -D build32/wineasio.dll.so $out/lib/wine/i386-unix/wineasio.dll.so
+    install -D build64/wineasio.dll $out/lib/wine/x86_64-windows/wineasio.dll
+    install -D build64/wineasio.dll.so $out/lib/wine/x86_64-unix/wineasio.dll.so
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/wineasio/wineasio";
+    description = "ASIO to JACK driver for WINE";
+    license = with licenses; [ gpl2 lgpl21 ];
+    maintainers = with maintainers; [ lovesegfault ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 0db927da5322..c78d9e3b9e0a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -36397,6 +36397,8 @@ with pkgs;
     wineRelease = "wayland";
   });
 
+  wineasio = callPackage ../applications/emulators/wineasio { };
+
   wishbone-tool = callPackage ../development/tools/misc/wishbone-tool { };
 
   with-shell = callPackage ../applications/misc/with-shell { };