nixpkgs-suyu/pkgs/development/tools/devpi-server/default.nix

 { stdenv, pythonPackages, nginx }:

pythonPackages.buildPythonApplication rec {
  name = "${pname}-${version}";
  pname = "devpi-server";
  version = "4.4.0";

  src = pythonPackages.fetchPypi {
    inherit pname version;
    sha256 = "0y77kcnk26pfid8vsw07v2k61x9sdl6wbmxg5qxnz3vd7703xpkl";
  };

  propagatedBuildInputs = with pythonPackages;
    [ devpi-common execnet itsdangerous pluggy waitress pyramid passlib ];
  checkInputs = with pythonPackages; [ nginx webtest pytest beautifulsoup4 pytest-timeout mock pyyaml ];
  preCheck = ''
    # These tests pass with pytest 3.3.2 but not with pytest 3.4.0.
    sed -i 's/test_basic/noop/' test_devpi_server/test_log.py
    sed -i 's/test_new/noop/' test_devpi_server/test_log.py
    sed -i 's/test_thread_run_try_again/noop/' test_devpi_server/test_replica.py
  '';
  checkPhase = ''
    runHook preCheck
    cd test_devpi_server/
    PATH=$PATH:$out/bin pytest --slow -rfsxX
  '';

  meta = with stdenv.lib;{
    homepage = http://doc.devpi.net;
    description = "Github-style pypi index server and packaging meta tool";
    license = licenses.mit;
    maintainers = with maintainers; [ makefu ];
  };
}