nixpkgs-suyu/pkgs/tools/networking/mu/default.nix

{ fetchurl, stdenv, sqlite, pkgconfig, autoconf, automake
, xapian, glib, gmime, texinfo , emacs, guile
, gtk3, webkit, libsoup, icu, withMug ? false /* doesn't build with current gtk3 */ }:

stdenv.mkDerivation rec {
  version = "0.9.12";
  name = "mu-${version}";

  src = fetchurl {
    url = "https://github.com/djcb/mu/archive/v${version}.tar.gz";
    sha256 = "1bxryacmas2llj68m2dv8dr1vwx8f5k2i2azh69jajkpqx7i4wdq";
  };

  buildInputs =
    [ sqlite pkgconfig autoconf automake xapian
      glib gmime texinfo emacs guile libsoup icu ]
    ++ stdenv.lib.optional withMug [ gtk3 webkit ];

  preConfigure = ''
    autoreconf -i
  '';

  preBuild = ''
    # Fix mu4e-builddir (set it to $out)
    substituteInPlace mu4e/mu4e-meta.el.in \
      --replace "@abs_top_builddir@" "$out"

    # We install msg2pdf to bin/msg2pdf, fix its location in elisp
    substituteInPlace mu4e/mu4e-actions.el \
      --replace "/toys/msg2pdf/msg2pdf" "/bin/msg2pdf"
  '';

  # Install mug and msg2pdf
  postInstall = stdenv.lib.optionalString withMug ''
    cp -v toys/msg2pdf/msg2pdf $out/bin/
    cp -v toys/mug/mug $out/bin/
  '';

  meta = {
    description = "A collection of utilties for indexing and searching Maildirs";
    license = stdenv.lib.licenses.gpl3Plus;
    homepage = "http://www.djcbsoftware.nl/code/mu/";
    platforms = stdenv.lib.platforms.mesaPlatforms;
    maintainers = with stdenv.lib.maintainers; [ antono the-kenny ];
  };
}